¿Cómo puedo combinar hashes en Perl?

Echa un vistazo perlfaq4: Cómo combinar dos hashes. Ya hay mucha información buena en la documentación de Perl y puede tenerla de inmediato en lugar de esperar a que alguien más la responda. :)

Antes de decidir fusionar dos hashes, debe decidir qué hacer si ambos hashes contienen claves que son las mismas y si desea dejar los hashes originales como estaban.

Si desea conservar los hashes originales, copie un hash (%hash1) a un nuevo hash (%new_hash), luego agregue las claves del otro hash (%hash2 al nuevo hash. Comprobar que la clave ya existe en %new_hash te da la oportunidad de decidir qué hacer con los duplicados:

my %new_hash = %hash1; # make a copy; leave %hash1 alone

foreach my $key2 ( keys %hash2 )
    {
    if( exists $new_hash{$key2} )
        {
        warn "Key [$key2] is in both hashes!";
        # handle the duplicate (perhaps only warning)
        ...
        next;
        }
    else
        {
        $new_hash{$key2} = $hash2{$key2};
        }
    }

Si no desea crear un nuevo hash, todavía puede usar esta técnica de bucle; simplemente cambie %new_hash a %hash1.

foreach my $key2 ( keys %hash2 )
    {
    if( exists $hash1{$key2} )
        {
        warn "Key [$key2] is in both hashes!";
        # handle the duplicate (perhaps only warning)
        ...
        next;
        }
    else
        {
        $hash1{$key2} = $hash2{$key2};
        }
    }

Si no le importa que un hash sobrescriba las claves y los valores del otro, podría usar un hash slice para agregar un hash a otro. En este caso, los valores de % hash2 reemplazan los valores de %hash1 cuando tienen claves en común:

@hash1{ keys %hash2 } = values %hash2;

Esta es una vieja pregunta, pero sale muy alto en mi búsqueda de Google para 'perl merge hashes' - y sin embargo no menciona el muy útil módulo CPAN Hash:: Merge

Para referencias hash. Debes usar llaves como las siguientes:

$hash_ref1 = {%$hash_ref1, %$hash_ref2};

Y no la respuesta sugerida arriba usando paréntesis:

$hash_ref1 = ($hash_ref1, $hash_ref2);