¿Cómo puedo restablecer una secuencia en Oracle?

Un reinicio verdadero no es posible AFAIK. (Por favor corríjame si me equivoco!).

Sin embargo, si desea configurarlo en 0, solo puede eliminarlo y recrearlo.

Si desea establecer un valor específico, puede establecer el INCREMENTO a un valor negativo y obtener el siguiente valor.

Es decir, si su secuencia está en 500, puede configurarla en 100 a través de

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

Este es mi enfoque:

1. suelta la secuencia
2. recrearlo

Ejemplo:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

Mi enfoque es una pequeña extensión del ejemplo de Dougman.

Las extensiones son...

Pase el valor de semilla como parámetro. ¿Por qué? Me gusta llamar a la cosa que restablece la secuencia de nuevo a el ID máximo utilizado en alguna tabla. Termino llamando a este proc desde otro script que ejecuta múltiples llamadas para un montón de secuencias, restableciendo nextval de nuevo a algún nivel que es lo suficientemente alto como para no causar violaciónes de clave primaria donde estoy usando la secuencia de valor de un identificador único.

También honra el anterior minvalue. De hecho, puede empujar el siguiente valor cada vez más altosi el deseado p_valo minvalue existente son más altos que el valor siguiente actual o calculado.

Lo mejor de todo es que se puede llamar para restablecer a un valor especificado, y simplemente espere hasta que vea el procedimiento wrapper "fix all my sequences" al final.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Ese procedimiento es útil por sí mismo, pero ahora agreguemos otro que lo llame y especifique todo programáticamente con una convención de nomenclatura de secuencia y buscando el valor máximo utilizado en una tabla/campo existente...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Ahora estamos cocinando con gas!

El procedimiento anterior comprobará el valor máximo de un campo en una tabla, construye un nombre de secuencia a partir del par tabla/campo e invoca "Reset_Sequence" con ese valor máximo detectado.

La pieza final de este rompecabezas y la guinda del pastel viene después...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

En mi base de datos actual hay alrededor de un centenar de secuencias que se están restableciendo a través de este mecanismo, por lo que hay 97 llamadas más a Reset_Sequence_to_Data en ese procedimiento anterior.

El Amor? ¿Odiarlo? Indiferente?

alter sequence serial restart start with 0;

Esta característica es nueva en Oracle 12c. Está no incluida en la documentación oficial . Lo encontré en scripts generados por el paquete Oracle DBMS_METADATA_DIFF .

ADVERTENCIA: He usado esta característica varias veces en sistemas de producción y en mi opinión está bien usar este comando en scripts ad-hoc. Pero es posible que no desee incluirlo en un procedimiento como parte de una solicitud. Creé una solicitud de servicio de Oracle preguntando sobre esto característica; no es solo un error de documentación, es una característica no compatible. Es posible que el comando desaparezca algún día, como WM_CONCAT. (Aunque creo que es poco probable-la sintaxis de Oracle rara vez desaparece, y es una característica simple utilizada internamente en al menos dos lugares.)

El siguiente script establece la secuencia en el valor deseado:

Dada una secuencia recién creada llamada PCS_PROJ_KEY_SEQ y tabla PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Este procedimiento almacenado reinicia mi secuencia:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Hay otra forma de restablecer una secuencia en Oracle: establecer las propiedades maxvalue y cycle. Cuando el nextval de la secuencia golpea el maxvalue, si la propiedad cycle se establece entonces comenzará de nuevo desde el minvalue de la secuencia.

La ventaja de este método en comparación con la configuración de un negativo increment by es que la secuencia se puede seguir utilizando mientras se ejecuta el proceso de restablecimiento, lo que reduce la posibilidad de que tenga que tomar algún tipo de interrupción para hacer el restablecimiento.

El valor de maxvalue tiene que ser mayor que el nextval actual, por lo que el procedimiento a continuación incluye un parámetro opcional que permite un búfer en caso de que se acceda de nuevo a la secuencia entre la selección del nextval en el procedimiento y la configuración de la propiedad cycle.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

El procedimiento as stands still permite la posibilidad de que otra sesión obtenga el valor 0, lo que puede ser o no un problema para usted. Si lo es, siempre podrías:

• Establecer minvalue 1 en el primer alter
• Excluir el segundo nextval fetch
• Mueva la instrucción para establecer la propiedad nocycle a otro procedimiento, que se ejecutará en una fecha posterior (suponiendo que desee hacer esto).

1) Supongamos que crea una SECUENCIA como se muestra a continuación:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Ahora obtiene valores de SEQUENCE. Digamos que he buscado cuatro veces como se muestra a continuación.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Después de ejecutar los cuatro comandos anteriores, el valor de la SECUENCIA será 4. Ahora supongamos que he restablecido el valor de la SECUENCIA a 1 de nuevo. Siga los siguientes pasos. Siga todos los pasos en el mismo orden que se muestra abajo:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Alterar el valor DE INCREMENTO de la secuencia, incrementarlo y luego alterarlo de nuevo es bastante indoloro, además de que tiene el beneficio adicional de no tener que restablecer todas las concesiones como lo haría si hubiera eliminado/recreado la secuencia.

Creo un bloque para restablecer todas mis secuencias:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Aquí hay un procedimiento más robusto para alterar el siguiente valor devuelto por una secuencia, más mucho más.

• En primer lugar, protege contra ataques de inyección SQL ya que ninguna de las cadenas pasadas se utilizan para crear directamente ninguna de las instrucciones SQL dinámicas,
• En segundo lugar, evita que el siguiente valor de secuencia se establezca fuera de los límites de los valores de secuencia min o max. El next_value será != min_value y entre min_value y max_value.
• En tercer lugar toma la configuración actual (o propuesta) increment_by, así como todas las demás configuraciones de secuencia en cuenta al limpiar.
• Cuarto todos los parámetros excepto el primero son opcionales y a menos que se especifique toman el ajuste de secuencia actual como valores predeterminados. Si no se especifican parámetros opcionales, no se realiza ninguna acción.
• Finalmente, si intenta alterar una secuencia que no existe (o que no es propiedad del usuario actual), se producirá un error ORA-01403: no data found.

Aquí está el código:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

En mi proyecto, una vez que sucedió que alguien ingresó manualmente los registros sin usar sequence, por lo tanto, tengo que restablecer el valor de la secuencia manualmente, para lo cual escribí debajo del fragmento de código sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Tenga en cuenta que el código anterior funcionará si la secuencia está retrasada.

Jezus, toda esta programación para solo un reinicio de índice... Tal vez soy un idiota, pero para pre-oracle 12 (que tiene una función de reinicio), lo que está mal con un simpel:

drop sequence blah;
create sequence blah 

?

Puede usar la opción de CICLO, que se muestra a continuación:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

En este caso, cuando la secuencia alcance MAXVALUE (100), se reciclará al MINVALUE (0).

En el caso de una secuencia decrementada, la secuencia se reciclaría al VALOR MÁXIMO.

He aquí cómo hacer que todas las secuencias de incremento automático coincidan con los datos reales:

1. Crear un procedimiento para imponer el siguiente valor como ya se describió en este hilo:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;
   

2. Crear otro procedimiento para conciliar todas las secuencias con el contenido real:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;
   

NOTAS:

1. El procedimiento extrae nombres del código de activación y no depende de las convenciones de nomenclatura
2. Para verificar el código generado antes de la ejecución, cambie los comentarios al último dos líneas

Hago una alternativa que el usuario no necesita conocer los valores, el sistema obtiene y usa variables para actualizar.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;